feat: add imageglass from AUR

imageglass/.SRCINFO

@@ -0,0 +1,21 @@
+pkgbase = imageglass
+	pkgdesc = lightweight, versatile image viewer
+	pkgver = 10.0.0.314_beta_1
+	pkgrel = 1
+	url = https://imageglass.org
+	arch = x86_64
+	license = GPL-3.0-only
+	makedepends = dotnet-sdk
+	makedepends = git
+	depends = fontconfig
+	depends = glibc
+	depends = hicolor-icon-theme
+	depends = libgomp
+	options = !strip
+	options = !debug
+	source = imageglass::git+https://github.com/d2phap/ImageGlass.git#tag=10.0.0.314-beta-1
+	source = imageglass.desktop
+	sha256sums = 72c1473abea880eaa50de0435a0a9a1d0ac12ed6c14cbf6467ae6c1c62844926
+	sha256sums = b31814a355395b002b8bd2dedc9107f5c288a56998df6e9894379900b6a7c560
+
+pkgname = imageglass

imageglass/.gitignore

@@ -0,0 +1,8 @@
+# Ignore everything
+*
+
+# But not these files...
+!.gitignore
+!PKGBUILD
+!.SRCINFO
+!imageglass.desktop

imageglass/PKGBUILD

@@ -0,0 +1,57 @@
+# Maintainer: ludwinahesse
+pkgname="imageglass"
+_pkgver="10.0.0.314-beta-1"
+pkgver=${_pkgver//-/_}
+pkgrel=1
+pkgdesc="lightweight, versatile image viewer"
+url="https://imageglass.org"
+license=('GPL-3.0-only')
+arch=('x86_64')
+
+depends=(
+  'fontconfig'
+  'glibc'
+  'hicolor-icon-theme'
+  'libgomp'
+)
+makedepends=(
+  'dotnet-sdk'
+  'git'
+)
+
+options=('!strip' '!debug')
+_pkgsrc="$pkgname-$pkgver"
+_pkgext="tar.gz"
+source=(
+  "${pkgname}"::"git+https://github.com/d2phap/ImageGlass.git#tag=$_pkgver"
+  'imageglass.desktop'
+)
+sha256sums=('72c1473abea880eaa50de0435a0a9a1d0ac12ed6c14cbf6467ae6c1c62844926'
+            'b31814a355395b002b8bd2dedc9107f5c288a56998df6e9894379900b6a7c560')
+build() {
+  cd "$srcdir/${pkgname}/v10/"
+  dotnet publish ImageGlass.Linux/ImageGlass.Linux.csproj \
+    -c Release \
+    -r linux-x64 \
+    -p:Platform=x64 \
+    -p:PublishAot=true \
+    -p:PublishSingleFile=true \
+    -p:PublishTrimmed=true \
+    -o ./artifacts/publish/linux-x64 \
+    --self-contained true
+}
+
+package() {
+  cd "$srcdir/${pkgname}/v10/artifacts/publish/linux-x64"
+  for file in ImageGlass libHarfBuzzSharp.so libSkiaSharp.so Magick.Native-Q8-OpenMP-x64.dll.so; do
+    install -Dm755 "$file" "$pkgdir/usr/lib/$pkgname/$file"
+  done
+  install -dm755 "$pkgdir/usr/bin"
+  ln -s "/usr/lib/$pkgname/ImageGlass" "$pkgdir/usr/bin/$pkgname"
+  # copy resources
+  cp -r "$srcdir/${pkgname}/v10/assets/resources/"* "$pkgdir/usr/lib/$pkgname/"
+  # install desktop file and icon
+  install -Dm644 "$srcdir/$pkgname.desktop" "$pkgdir/usr/share/applications/$pkgname.desktop"
+  install -Dm644 "$srcdir/${pkgname}/v10/assets/Logo.svg" "$pkgdir/usr/share/icons/hicolor/scalable/apps/$pkgname.svg"
+  install -Dm644 "$srcdir/${pkgname}/v10/assets/Logo512.png" "$pkgdir/usr/share/icons/hicolor/512x512/apps/$pkgname/$pkgname.png"
+}

imageglass/imageglass.desktop

@@ -0,0 +1,10 @@
+[Desktop Entry]
+Name=ImageGlass
+Comment=A lightweight, versatile image viewer
+Exec=imageglass %F
+Icon=imageglass
+Terminal=false
+Type=Application
+Categories=Graphics;Viewer;
+MimeType=image/jpeg;image/png;image/gif;image/bmp;image/tiff;image/svg+xml;image/webp;image/avif;image/heic;image/heif;image/x-icon;image/vnd.microsoft.icon;image/x-tga;image/x-xcf;image/x-xbitmap;image/x-portable-pixmap;image/x-portable-graymap;image/x-portable-bitmap;image/x-portable-anymap;image/x-exr;image/x-radiance;image/x-dds;image/x-adobe-dng;image/x-canon-cr2;image/x-canon-cr3;image/x-canon-crw;image/x-nikon-nef;image/x-nikon-nrw;image/x-sony-arw;image/x-sony-sr2;image/x-sony-srf;image/x-panasonic-raw;image/x-panasonic-rw2;image/x-olympus-orf;image/x-fuji-raf;image/x-kodak-dcr;image/x-pentax-pef;image/x-samsung-srw;image/vnd.adobe.photoshop;
+StartupWMClass=ImageGlass