Rename filebrowser-service-menu-git to filebrowser-service-menu | Update filebrowser-service-menu to 1.0.1

filebrowser-service-menu/PKGBUILD

@@ -0,0 +1,38 @@
+# Maintainer: Dominykas Svetikas <dominykas@svetikas.lt>
+
+pkgname=filebrowser-service-menu
+pkgver=1.0.1
+pkgrel=1
+pkgdesc="A service menu for KDE to share files via Filebrowser."
+arch=('x86_64')
+url="https://github.com/JustAnyones/FilebrowserServiceMenu"
+license=('MIT')
+makedepends=('go' 'git')
+depends=('glibc')
+source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
+sha256sums=('91ddadee3b7d72c44adafe94c37de0cf33917627c103613baec7b2e36ff0a7c8')
+
+prepare() {
+    tar -xzf "$pkgname-$pkgver.tar.gz"
+    cd "FilebrowserServiceMenu-${pkgver}" || return
+    export GOPATH="${srcdir}"
+    go mod download
+}
+
+build() {
+    cd "FilebrowserServiceMenu-${pkgver}" || return
+    #export CGO_ENABLED=0
+    export CGO_CPPFLAGS="${CPPFLAGS}"
+    export CGO_CFLAGS="${CFLAGS}"
+    export CGO_CXXFLAGS="${CXXFLAGS}"
+    export CGO_LDFLAGS="${LDFLAGS}"
+    export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
+    go build -v -o filebrowser-service-menu ./cmd/main.go
+}
+
+package() {
+    cd "FilebrowserServiceMenu-${pkgver}" || return
+    install -D -m755 filebrowser-service-menu "$pkgdir/usr/bin/filebrowser-service-menu"
+    install -D -m644 build/shareViaFilebrowser.desktop \
+        "$pkgdir/usr/share/kio/servicemenus/shareViaFilebrowser.desktop"
+}