Add random-file-picker-git

random-file-picker-git/.SRCINFO

@@ -0,0 +1,21 @@
+pkgbase = random-file-picker-git
+	pkgdesc = A tool for picking random files from a directory for viewing.
+	pkgver = r2.ed55631
+	pkgrel = 1
+	url = https://git.svetikas.lt/JustAnyone/random-file-picker
+	arch = any
+	license = MIT
+	makedepends = python-build
+	makedepends = python-installer
+	makedepends = python-wheel
+	makedepends = python-setuptools
+	makedepends = python-uv
+	makedepends = git
+	depends = python
+	depends = python-requests
+	provides = random-file-picker
+	conflicts = random-file-picker
+	source = git+https://git.svetikas.lt/JustAnyone/random-file-picker.git
+	md5sums = SKIP
+
+pkgname = random-file-picker-git

random-file-picker-git/.gitignore

@@ -0,0 +1,4 @@
+/*
+!/.gitignore
+!/.SRCINFO
+!/PKGBUILD

random-file-picker-git/PKGBUILD

@@ -0,0 +1,30 @@
+# Maintainer: Dominykas Svetikas <dominykas@svetikas.lt>
+pkgname=random-file-picker-git
+_pkgname=random-file-picker
+pkgver=r2.ed55631
+pkgrel=1
+pkgdesc='A tool for picking random files from a directory for viewing.'
+arch=('any')
+url='https://git.svetikas.lt/JustAnyone/random-file-picker'
+license=('MIT')
+depends=('python' 'python-requests')
+makedepends=('python-build' 'python-installer' 'python-wheel' 'python-setuptools' 'python-uv' 'git')
+conflicts=('random-file-picker')
+provides=('random-file-picker')
+source=("git+$url.git")
+md5sums=('SKIP')
+
+pkgver() {
+    cd "$_pkgname"
+    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
+}
+
+build() {
+    cd "$_pkgname"
+    uv build --wheel --no-build-isolation --python /usr/bin/python3
+}
+
+package() {
+    cd "$_pkgname"
+    python -m installer --destdir="$pkgdir" dist/*.whl
+}