# Maintainer: Dominykas Svetikas <dominykas@svetikas.lt>

pkgname=filebrowser-service-menu
pkgver=1.0.3
pkgrel=1
pkgdesc="A service menu for KDE to share files via Filebrowser."
arch=('x86_64')
url="https://github.com/JustAnyones/FilebrowserServiceMenu"
license=('MIT')
makedepends=('go' 'git')
depends=('glibc')
conflicts=('filebrowser-service-menu-git')
source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
sha256sums=('34d71fe29e3cd32ea37f15aef778846a3a1201d8b404f470fdcd837764f83ca6')

prepare() {
    tar -xzf "$pkgname-$pkgver.tar.gz"
    cd "FilebrowserServiceMenu-${pkgver}" || return
    export GOPATH="${srcdir}"
    go mod download
}

build() {
    cd "FilebrowserServiceMenu-${pkgver}" || return
    #export CGO_ENABLED=0
    export CGO_CPPFLAGS="${CPPFLAGS}"
    export CGO_CFLAGS="${CFLAGS}"
    export CGO_CXXFLAGS="${CXXFLAGS}"
    export CGO_LDFLAGS="${LDFLAGS}"
    export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
    go build -v -o filebrowser-service-menu ./cmd/main.go
}

package() {
    cd "FilebrowserServiceMenu-${pkgver}" || return
    install -D -m755 filebrowser-service-menu "$pkgdir/usr/bin/filebrowser-service-menu"
    install -D -m644 build/shareViaFilebrowser.desktop \
        "$pkgdir/usr/share/kio/servicemenus/shareViaFilebrowser.desktop"
}