# Maintainer: Dominykas Svetikas <archlinux@svetikas.lt>
# Maintainer: ludwinahesse
pkgname="imageglass"
_pkgver="10.0.6.906"
pkgver=${_pkgver//-/_}
pkgrel=1
pkgdesc="A Fast, Seamless Photo Viewer"
url="https://imageglass.org"
license=('GPL-3.0-only')
arch=('x86_64')

depends=(
  'fontconfig'
  'glibc'
  'hicolor-icon-theme'
  'libgomp'
)
makedepends=(
  'dotnet-sdk'
  'git'
)

options=('!strip' '!debug')
_pkgsrc="$pkgname-$pkgver"
_pkgext="tar.gz"
source=(
  "${pkgname}"::"git+https://github.com/d2phap/ImageGlass.git#tag=$_pkgver"
)
sha256sums=('SKIP')
build() {
  cd "$srcdir/${pkgname}/source/"
  dotnet publish ImageGlass.Linux/ImageGlass.Linux.csproj \
    -c Release \
    -r linux-x64 \
    -p:Platform=x64 \
    -p:PublishAot=true \
    -p:PublishSingleFile=true \
    -p:PublishTrimmed=true \
    -o ./artifacts/publish/linux-x64 \
    --self-contained true
}

package() {
  cd "$srcdir/${pkgname}/source/artifacts/publish/linux-x64"
  for file in ImageGlass libHarfBuzzSharp.so libSkiaSharp.so Magick.Native-Q16-HDRI-OpenMP-x64.dll.so; do
    install -Dm755 "$file" "$pkgdir/usr/lib/$pkgname/$file"
  done
  install -dm755 "$pkgdir/usr/bin"
  ln -s "/usr/lib/$pkgname/ImageGlass" "$pkgdir/usr/bin/$pkgname"
  # copy resources
  cp -r "$srcdir/${pkgname}/source/__assets/__app/"* "$pkgdir/usr/lib/$pkgname/"

  # install desktop file and icon
  install -Dm644 "$srcdir/${pkgname}/source/__assets/linux/flatpak/io.github.d2phap.imageglass.desktop" "$pkgdir/usr/share/applications/$pkgname.desktop"
  install -Dm644 "$srcdir/${pkgname}/source/__assets/logo_c.svg" "$pkgdir/usr/share/icons/hicolor/scalable/apps/$pkgname.svg"
  install -Dm644 "$srcdir/${pkgname}/source/__assets/logo_c_512.png" "$pkgdir/usr/share/icons/hicolor/512x512/apps/$pkgname/$pkgname.png"

  # Update the icon
  sed -i "s|Icon=.*|Icon=imageglass|" \
    "${pkgdir}/usr/share/applications/$pkgname.desktop"
}