# Maintainer: Dominykas Svetikas <dominykas@svetikas.lt>

pkgname=filebrowser-service-menu-git
pkgver=1.0.0
pkgrel=1
pkgdesc="A service menu for KDE to share files via Filebrowser."
arch=('x86_64')
url="https://github.com/JustAnyones/FilebrowserServiceMenu"
license=('MIT')
makedepends=('go' 'git')
source=("$pkgname-$pkgver::git+$url.git")
sha256sums=('SKIP')

prepare() {
    cd "${pkgname}-${pkgver}" || return
    export GOPATH="${srcdir}"
    go mod download
}

build() {
    cd "${pkgname}-${pkgver}" || return
    #export CGO_ENABLED=0
    export CGO_CPPFLAGS="${CPPFLAGS}"
    export CGO_CFLAGS="${CFLAGS}"
    export CGO_CXXFLAGS="${CXXFLAGS}"
    export CGO_LDFLAGS="${LDFLAGS}"
    export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
    go build -v -o filebrowser-service-menu ./cmd/main.go
}

package() {
    cd "$pkgname-$pkgver" || return
    install -D -m755 filebrowser-service-menu "$pkgdir/usr/bin/filebrowser-service-menu"
    install -D -m644 build/shareViaFilebrowser.desktop \
        "$pkgdir/usr/share/kio/servicemenus/shareViaFilebrowser.desktop"
}