# Maintainer: Mario Ortiz Manero <marioortizmanero@gmail.com>
# Maintainer: Daniel Vogt <marioortizmanero@gmail.com>
# Maintainer: Dominykas Svetikas <dominykas@svetikas.lt>
pkgname=moodle-dl-git
_pkgname=Moodle-DL
pkgver=2.3.13.r2.g9aae52a
pkgrel=1
pkgdesc='Moodle downloader to download course content automatically'
arch=('any')
url='https://github.com/JustAnyones/Moodle-DL'
license=('GPL3')
depends=('python' 'ffmpeg' 'python-sentry_sdk' 'python-colorama'
         'yt-dlp' 'python-certifi' 'python-html2text'
         'python-requests' 'python-xmpppy' 'python-aiodns'
         'python-aiofiles' 'python-aiohttp' 'python-colorlog'
         'python-readchar')
makedepends=('python-build' 'python-installer' 'python-wheel' 'git')
conflicts=('moodle-dl')
provides=('moodle-dl')
source=("git+$url.git")
md5sums=('SKIP')

pkgver() {
    cd "$_pkgname"
    git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
    cd "$_pkgname"
    python -m build --wheel --no-isolation
}

package() {
    cd "$_pkgname"
    python -m installer --destdir="$pkgdir" dist/*.whl
}