45 lines
1.8 KiB
Bash
45 lines
1.8 KiB
Bash
# Maintainer: Dominykas Svetikas <[email protected]>
|
|
pkgname=thumbs-bin
|
|
_pkgname=thumbs
|
|
pkgver=0.5.3
|
|
pkgrel=1
|
|
pkgdesc="Thumbnail management utility"
|
|
arch=('x86_64')
|
|
url="https://github.com/gourlaysama/thumbs"
|
|
license=('Apache-2.0')
|
|
depends=() # musl
|
|
optdepends=(
|
|
'systemd: cleanup timer support'
|
|
)
|
|
provides=("${_pkgname}")
|
|
conflicts=("${_pkgname}")
|
|
source=("${url}/releases/download/v${pkgver}/${_pkgname}-${pkgver}-x86_64-unknown-linux-musl.tar.gz")
|
|
sha256sums=('f826b42e218527319b436052cb27cd6cc99661883c21d502018555b3c25ec397')
|
|
|
|
package() {
|
|
cd "${srcdir}/${_pkgname}-${pkgver}-x86_64-unknown-linux-musl"
|
|
|
|
# The binary
|
|
install -Dm755 "${_pkgname}" "${pkgdir}/usr/bin/${_pkgname}"
|
|
|
|
# Shell completions
|
|
install -Dm644 complete/thumbs.bash "${pkgdir}/usr/share/bash-completion/completions/${_pkgname}"
|
|
install -Dm644 complete/thumbs.fish "${pkgdir}/usr/share/fish/vendor_completions.d/${_pkgname}.fish"
|
|
install -Dm644 complete/_thumbs "${pkgdir}/usr/share/zsh/site-functions/_${_pkgname}"
|
|
|
|
# Systemd user services
|
|
install -Dm644 extra/systemd-user/thumbnail-cleanup.service "${pkgdir}/usr/lib/systemd/user/thumbnail-cleanup.service"
|
|
install -Dm644 extra/systemd-user/thumbnail-cleanup.timer "${pkgdir}/usr/lib/systemd/user/thumbnail-cleanup.timer"
|
|
|
|
# TODO: Nautilus extension
|
|
#install -Dm644 extra/nautilus/thumbs-nautilus.py "${pkgdir}/usr/share/nautilus-python/extensions/thumbs-nautilus.py"
|
|
|
|
# Man pages
|
|
install -Dm644 thumbs.1.gz "${pkgdir}/usr/share/man/man1/thumbs.1.gz"
|
|
# And the rest of the docs
|
|
install -Dm644 README.md "${pkgdir}/usr/share/doc/${_pkgname}/README.md"
|
|
install -Dm644 CHANGELOG.md "${pkgdir}/usr/share/doc/${_pkgname}/CHANGELOG.md"
|
|
install -Dm644 NOTICE "${pkgdir}/usr/share/doc/${_pkgname}/NOTICE"
|
|
install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
|
|
}
|